0 'WRITTEN BY EUGENY BRYCHKOV 03 SEP 2014
10 PRINT"KONAMI SCC'S DAC OUTPUT TEST PROGRAM"
20 RESTORE 1000
30 FORI=0TO24:READA:POKE&H9000+I,A:NEXTI
40 DEFUSR=&H9000:DEFUSR1=&H900D:DEFUSR2=&H9019
50 INPUT"SELECT SLOT (1,2)";S:IFS<>1ANDS<>2THENPRINT"ERROR":GOTO50
60 POKE&H9001,S:POKE&H900E,S
70 PRINT"CHECKING FOR SCC"
80 A1=&H9013:A2=&H9010:A3=&H9011:A4=&H9003:A5=&H9004
90 'SWITCHING TO REGISTER PAGE IN BANK 3
100 POKEA1,63:POKEA2,0:POKEA3,&H90:A=USR1(0)
110 'MUTING CHANNELS
120 POKEA1,0:POKEA2,&H8F:POKEA3,&H98:A=USR1(0)
130 'CHECKING FOR R/W REGISTER AREA
140 POKEA5,&H98
150 FORI=0TO127
160 POKEA1,I+1:POKEA2,I:A=USR1(0)
170 POKEA4,I:A=USR(0)
180 IFPEEK(&HC000)<>I+1THENPRINT"R/W FAIL AT REG: ";I:STOP
190 NEXT I
200 PRINT"REGISTER AREA FOUND AND TESTED"
210 'CLEARING DEFORMATION REG
220 POKEA1,0:POKEA2,&HE0:A=USR1(0)
230 'TESTING CHANNELS
231 PRINT"SILENCE TEST"
232 'CLEAR ALL WAVEFORMS
233 FORI=0TO127:POKEA1,0:POKEA2,I:A=USR1(0):NEXTI
234 'SET ALL VOLUME TO MAX
235 FORI=0TO4:POKEA2,&H8A+I:POKEA1,15:A=USR1(0)
236 'ENABLE ALL CHANNELS
237 POKEA1,31:POKEA2,&H8F:A=USR1(0)
238 PRINT"PRESS SPACE KEY TO CONTINUE":A$=INPUT$(1)
239 POKEA1,0:POKEA2,&H8F:A=USR1(0)
240 PRINT"SINE TEST - SPACE KEY TO SUSPEND"
241 FORJ=0TO3
250 RESTORE1010
260 FORI=0TO31:READA:IFA<0THENA=256+A
270 POKEA1,A:POKEA2,J*32+I:A=USR1(0):NEXTI
280 NEXTJ
300 FORC=0TO4
310 'RESET VOLUME
320 POKEA2,&H8A+C:POKEA1,0:A=USR1(0)
330 'TURN CHANNEL ON
340 POKEA2,&H8F:POKEA1,2^C:A=USR1(0)
350 FORV=1TO15:POKEA2,&H8A+C:POKEA1,V:A=USR1(0)
360 FORI=0TO4:FQ=(I+1)*200:F=111875!/FQ
370 PRINT"CH";C;" FREQ";STR$(FQ);"Hz VOL";V;"   ";CHR$(13);
380 POKEA2,&H8F:POKEA1,0:A=USR1(0)
390 POKEA1,FMOD256:POKEA2,&H80+C*2:A=USR1(0)
400 POKEA1,F/256:POKEA2,&H81+C*2:A=USR1(0)
410 POKEA2,&H8F:POKEA1,2^C:A=USR1(0)
420 FORK=0TO50:NEXTK:A$=INKEY$:IFA$<>""THENA$=INPUT$(1)
430 NEXTI
440 NEXTV
450 NEXTC
460 POKEA1,0:POKEA2,&H8F:A=USR1(0):PRINT
470 STOP
1000 'READ SCC MEMORY
1001 DATA &H3E,1,&H21,0,&H40,&HCD,12,0,&HFB,&H32,0,&HC0,&HC9
1002 'WRITE SCC MEMORY
1003 DATA &H3E,1,&H21,0,&H50,&H1E,1,&HCD,&H14,0,&HFB,&HC9
1010 'SINE WAVE
1011 DATA 0,24,48,70,89,105,117,124
1012 DATA 127,124,117,105,89,70,48,24
1013 DATA 0,-24,-48,-70,-89,-105,-117,-124
1014 DATA -127,-124,-117,-105,-89,-70,-48,-24